相關文章

D1874e1e91bf405ed4fafae3be2d08bd 前文中我們介紹RTC 時鐘模組,該模組具備時間功能,並且為了斷電時依然可以保留時間,補足了Arduino開發板並沒有內置時鐘(Internal Clock)的功能,正好可以使用該時間模組。

 如下圖所示,可以見到Tiny RTC I2C 時鐘模組的外觀圖,模組採用DS1307晶片,若讀者需要更詳盡的資料,請參考拙作『Arduino投幣計時器(網路篇):Using Arduino to Develop a Timing Controlling Device via Internet』(曹永忠, 許智誠, & 蔡英德, 2015a, 2015b, 2015c, 2015f; 曹永忠, 許碩芳, 許智誠, & 蔡英德, 2015a, 2015b)內容關於RTC 時鐘模組。


圖 1 Tiny RTC I2C 時鐘模組

如下圖所示,我們可以參考時鐘模組之電路連接圖,先將電路連接完善後,攥寫與測試下列Tiny RTC I2C 時鐘模組測試程式。


圖 2 時鐘模組電路連接方式

校時問題

我們發現,若裝設新的開發版或不同時間點設置新裝置,我們必須透過使用者重新設定時間,或是修改程式,因為RTC 時鐘模組的初始化時間是寫在Arduino開發版的程式內,我們必須重新編譯程式,並上傳程式到Arduino開發版,這樣是非常不方便的,
如果我們具有自動校時的功能,完全不用使用者插手,這樣產業化的應用才能更實際,由於目前網路校時非常的方便,所以我們可以透過網路校時的方式來實踐這個機制,或許是一個相當完善的解決方案。

連接乙太網路擴充卡

為了能夠上網,本文使用W5100乙太網路擴充卡(曹永忠, 許智誠, & 蔡英德, 2015d, 2015e), 主要特色是把 TCP/IP Protocols (TCP, UDP, ICMP, IPv4 ARP, IGMP, PPPoE, Ethernet) 做在硬體電路上,減輕了單晶片(MCU )的負擔 (也就是 Arduino 開發板的負擔)。
Arduino 程式只要使用 Ethernet Library  便可以輕易完成連至網際網路的動作。 Arduino Ethernet Shield 使用加長型的 Pin header (如下圖.(a) & 下圖(b)),可以直接插到 Arduino 控制板上 (如下圖.(c) & 下圖.(d) & 下圖.(e)),而且原封不動地保留了 Arduino 控制板的 Pin Layout,讓使用者可以在它上面疊其它的擴充板(如下圖.(c) & 下圖.(d) & 下圖(e))。
比較新的 Ethernet Shield 增加了 micro-SD card 插槽(如下圖.(a)),可以用來儲存檔案,你可以用 Arduino 內建的 SD library 來存取板子上的 SD card。


(a)正面圖


(b).背面圖


(c).堆疊圖


(d).側面圖


(e).網路接腳圖


(f).網路接線圖

圖 3 Ethernet Shield(W5100)

首先,組立W5100 以太網路模組是非常容易的一件事,如下圖所示,只要將W5100 以太網路模組堆疊到任何Arduino開發板之上就可以了。


圖 4 將Arduino開發板與W5100 以太網路模組堆疊組立

之後,在將組立好的W5100 以太網路模組,如下圖所示,只要將USB線差到Arduino開發板,再將RJ 45的網路線一端插到W5100 以太網路模組,另一端插到可以上網的集線器(Switch HUB)的任何一個區域網路接口(Lan Port)就可以了(曹永忠, 許智誠, et al., 2015d, 2015e)。


圖 5接上電源與網路線的W5100 以太網路模組堆疊卡

取得網路校時時間資料

我們將Arduino 開發板的驅動程式安裝好之後,我們打開Arduino 開發板的開發工具:Sketch IDE整合開發軟體,攥寫一段程式,如下表所示之網路校時測試程式,我們就可以透過W5100 以太網路模組堆疊卡取得網路校時時間。

表 1網路校時測試程式

網路校時測試程式(UdpNtpClient)
/*

 Udp NTP Client

 Get the time from a Network Time Protocol (NTP) time server
 Demonstrates use of UDP sendPacket and ReceivePacket
 For more on NTP time servers and the messages needed to communicate with them,
 see http://en.wikipedia.org/wiki/Network_Time_Protocol

 created 4 Sep 2010
 by Michael Margolis
 modified 9 Apr 2012
 by Tom Igoe

 This code is in the public domain.

 */

#include <SPI.h>
#include <Ethernet.h>
#include <EthernetUdp.h>

// Enter a MAC address for your controller below.
// Newer Ethernet shields have a MAC address printed on a sticker on the shield
byte mac[] = {
  0xAA, 0xBB, 0xCC, 0xDD, 0xEE, 0xFF
};
IPAddress ip(192, 168, 2, 200);     //fix ip
IPAddress dnServer(168, 95, 1, 1);    //dns ip
// the router's gateway address:
IPAddress gateway(192, 168, 2, 1);    //gateway ip
// the subnet:
IPAddress subnet(255, 255, 255, 0);     //sub mask


unsigned int localPort = 8888;       // local port to listen for UDP packets

char timeServer[] = "time.nist.gov"; // time.nist.gov NTP server

const int NTP_PACKET_SIZE = 48; // NTP time stamp is in the first 48 bytes of the message

byte packetBuffer[ NTP_PACKET_SIZE]; //buffer to hold incoming and outgoing packets

// A UDP instance to let us send and receive packets over UDP
EthernetUDP Udp;
int Ntpyr,Ntpmon,Ntpday,Ntphr,Ntpmin,Ntpsec ;

void setup()
{
  // Open serial communications and wait for port to open:
  Serial.begin(9600);
  while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }


  // start Ethernet and UDP
  if (Ethernet.begin(mac) == 0) {
    Serial.println("Failed to configure Ethernet using DHCP");
    // no point in carrying on, so do nothing forevermore:
  Ethernet.begin(mac, ip, dnServer, gateway, subnet);

  }
  Udp.begin(localPort);
}

void loop()
{
  sendNTPpacket(timeServer); // send an NTP packet to a time server

  // wait to see if a reply is available
  delay(1000);
  if ( Udp.parsePacket() ) {
    // We've received a packet, read the data from it
    Udp.read(packetBuffer, NTP_PACKET_SIZE); // read the packet into the buffer

    //the timestamp starts at byte 40 of the received packet and is four bytes,
    // or two words, long. First, esxtract the two words:

    unsigned long highWord = word(packetBuffer[40], packetBuffer[41]);
    unsigned long lowWord = word(packetBuffer[42], packetBuffer[43]);
    // combine the four bytes (two words) into a long integer
    // this is NTP time (seconds since Jan 1 1900):
    unsigned long secsSince1900 = highWord << 16 | lowWord;
    Serial.print("Seconds since Jan 1 1900 = " );
    Serial.println(secsSince1900);

    // now convert NTP time into everyday time:
    Serial.print("Unix time = ");
    // Unix time starts on Jan 1 1970. In seconds, that's 2208988800:
    const unsigned long seventyYears = 2208988800UL;
    // subtract seventy years:
    unsigned long epoch = secsSince1900 - seventyYears + 8 * 60*60 ;
    // print Unix time:
    Serial.println(epoch);
    Ntphr = (epoch  % 86400L) / 3600 ;
    Ntpmin = (epoch  % 3600) / 60 ;
    Ntpsec = epoch % 60 ;
    // print the hour, minute and second:
    Serial.print("The Taiwan time is ");       // UTC is the time at Greenwich Meridian (GMT)
   
    Serial.print(print2digits(Ntphr)); // print the hour (86400 equals secs per day)
    Serial.print(':');
    Serial.print(print2digits(Ntpmin)); // print the minute (3600 equals secs per minute)
    Serial.print(':');

    Serial.println(print2digits(Ntpsec)); // print the second
  }
  // wait ten seconds before asking for the time again
  delay(10000);
}

// send an NTP request to the time server at the given address
unsigned long sendNTPpacket(char* address)
{
  // set all bytes in the buffer to 0
  memset(packetBuffer, 0, NTP_PACKET_SIZE);
  // Initialize values needed to form NTP request
  // (see URL above for details on the packets)
  packetBuffer[0] = 0b11100011;   // LI, Version, Mode
  packetBuffer[1] = 0;     // Stratum, or type of clock
  packetBuffer[2] = 6;     // Polling Interval
  packetBuffer[3] = 0xEC;  // Peer Clock Precision
  // 8 bytes of zero for Root Delay & Root Dispersion
  packetBuffer[12]  = 49;
  packetBuffer[13]  = 0x4E;
  packetBuffer[14]  = 49;
  packetBuffer[15]  = 52;

  // all NTP fields have been given values, now
  // you can send a packet requesting a timestamp:
  Udp.beginPacket(address, 123); //NTP requests are to port 123
  Udp.write(packetBuffer, NTP_PACKET_SIZE);
  Udp.endPacket();
}

String  print2digits(int number) {
  String ttt ;
  if (number >= 0 && number < 10)
  {
     ttt =String("0")+String(number);
  }
  else
  {
     ttt =String(number);
  }
   return ttt ;
}

String  print4digits(int number) {
  String ttt ;
     ttt =String(number);
   return ttt ;
}

下載網址:https://github.com/brucetsao/techbang/tree/master/201602

如下圖所示,讀者可以看到本次實驗-網路校時測試程式結果畫面。


圖 6網路校時測試程式結果畫面

 

後面還有更多內容!

使用 Facebook 留言

發表回應

謹慎發言,尊重彼此。按此展開留言規則